short Stage

short PlDuCombat

short DummyHealth                ; Health of Dummy to damage the player

short SelSleeptTime                ; time which was selected in the original sleep dialogue

short SlEventChance                ; sets the chance if someting is happening while sleeping -2 lower , 0 normal, 2 higher
short SlEventIndoor                ; no indoor events
short SlEvenetHome                ; no events at home
short SlSnorr                        ; no snorring

short WellRested                    ; wellrested perk control
short DogPee                        ; Dog Spell control

short OneSecond                    ; control for one second timer
short SecCnt                        ; one second timer for sleep process
short TalkCnt                        ; timer for idletalk while sleeping
short SnorrFreq                    ; frequency of snorring (calculated with endurance)

short SleepDisturbed                ; is sleep interrupted
short SleepDisturbedChance    ; chance of interruption
short SleepPlayerChance
short SleepDisturbedType        ; type of interruption (with instant wake up 0 or continuing sleep 1)
short SleepDisturbedStart        ; when is the sleep interupted

short SleepNotCancled

float hcSleepdep                    ; Sleep Dep Value
float hcHunger
float hcDehydration

float RealSleepStartTime        ; Start of Sleep
float RealSleepStopTime        ; End of Sleep
float RealSleepTime                ; How long the player slept

float OrgTimeScale                ; 'original' time scale
float SleepTimeScale                ; faster sleep timescale

float TimerC
float TimerD
float TimerE
float TimerF

ref BedRef
ref DummyRef

short DummyPlBedMove        ; Invisible Bed to activate Sleep Menu
ref DummyPlBedMoveRef

Begin GameMode

; ---------------------------- Stage 1: preperations for later ani stages &  teddy settings

If Stage == 1

Set DummyRef to FNNsys0.DummyRef

; ------- get the Hardcore Values because they get lost if sleep is canceld for a strange reason

Set hcHunger to PlayerRef.GetAv hunger
Set hcDehydration to PlayerRef.GetAv Dehydration

; ------- 'goto sleep' ani is running, rotate dummyXmH pos at begin for later

If FNNsys0.organgle > 180                                            ; rotate dummy pos (actualy the XMH) for end animation
set FNNsys0.fangle to FNNsys0.organgle - 180
Else
set FNNsys0.fangle to FNNsys0.organgle + 180
EndIf
DummyXMHRef.SetAngle Z FNNsys0.fangle

Set DummyHealth    to DummyRef.GetAv Health                    ; get health from Dummy

; ------- calculate the chance of disturbance

Set SleepDisturbedChance to  1 + GetRandomPercent * 9 / 99    ; calculate a random number 1 to 10
Set SleepPlayerChance to (PlayerRef.GetAv Luck) + SlEventChance

;        PrintC "FNNsys: Stage1 SleepPlayerChance: %f SleepDisturbedChance: %f" SleepPlayerChance SleepDisturbedChance

If  SleepPlayerChance <= SleepDisturbedChance        ; check against player luck
Set SleepDisturbed to 1                                    ; is it a disturbed 1 one or a normal 0
;            PrintC "FNNsys: Stage 1 Disturbed"
EndIf

;        Set SleepDisturbed to 1                                        ; ------------------------->  Debug

; ------- check the configuration settings made by the player

If PlayerRef.GetAv Perception < GetrandomPercent/10    ; perception deciedes if the player wakes up instantly after the event
Set SleepDisturbedType to 0                                ; can be overriden by ambushscript
Else
Set SleepDisturbedType to 1
EndIf

If SlEvenetHome == 1                                        ; home config
If WellRested == 1                                        ; is player at home is checked by wellrested script on beds
Set SleepDisturbed to 0                                ; let him sleep
EndIf
EndIf

If SlEventIndoor == 1                                            ; Interior config
If PlayerRef.IsInInterior == 1                            ; is player in an interior
Set SleepDisturbed to 0                                ; let him sleep
EndIf
EndIf

If PlayerRef.Getav Endurance <= 5                ; snorr frequency depends on characters endurance
Set SnorrFreq to 4                                    ; snorr every cycle
ElseIf PlayerRef.Getav Endurance <= 7
Set SnorrFreq to 8                                    ; snorr every second cycle
Else
Set SnorrFreq to 12                                ; snorr every third ...
EndIf

Set TimerC to 12                                        ; get in bed time timer for the fallback (if dummy is a real dummy)
Set Stage to 2

EndIf

; ---------------------------- Stage 2: Wait till dummy has found the Bed if he is sleeping ask the player how long

If Stage == 2

If DummyRef.IsInCombat == 1 || PlayerRef.IsInCombat == 1
Set TimerE to 4
Set Stage to 5                                                ; Get out
EndIf

If DummyRef.GetSleeping == 3                                ; check if dummy has arrived and is sleeping

If DummyPlBedMove == 0
;                PrintC "FNNsys: Stage2 Fake Bed for Player is produced"
Set DummyPlBedMoveRef to PlayerRef.Placeatme FNNsysCardBedFake 1    ; make a fake bed for the 'player' to click on
DummyPlBedMoveRef.Setscale 0.01                ; it is made small so it isn't found normally
Set DummyPlBedMove to 1
Endif

If DummyPlBedMoveRef.HasLoaded3d
If DummyPlBedMove == 1
;                    PrintC "FNNsys: Stage2 Dummy Sleeps Player has activated the bed"
DummyPlBedMoveRef.Activate PlayerRef        ; he is so ask the player how long stage advance in menumode
Set DummyPlBedMove to 2
EndIf
EndIf

If DummyPlBedMove == 3                                    ; We are out of menumode
Set Stage to 3
EndIf

EndIf

if ( TimerC > 0 )                                                    ; fall back timer if the dummy doesn't find the bed
Set TimerC to ( TimerC - GetSecondsPassed )
else
;            PrintC "FNNsys: Stage2 TimeOut Dummy hasn't found the bed"
showmessage     FNNsysFilthyMsg                                            ; message to inform player we pretend the bed is filthy
DummyRef.RemoveScriptpackage FNNsysSleepWalkPackage    ; dummy walks to already rotated dummypos
DummyRef.AddScriptpackage FNNsysWakeWalkPackage
DummyRef.evp

Set TimerE to 10                                            ; 10 seconds for the animations
Set Stage to 5                                                ; skip sleep
endIf

EndIf

; ---------------------------- Stage 3: disturbance calculation, Sleep Dauer calculation

If Stage == 3

If DummyPlBedMove == 3

; ---- get rid of the fake bed

;            PrintC "FNNsys: Menumode 1012 FakeBed is removed"

DummyPlBedMoveRef.Disable
DummyPlBedMoveRef.MarkforDelete
Set DummyPlBedMove to 0

EndIf

If DummyRef.IsInCombat == 1 || PlayerRef.IsInCombat == 1
Set TimerE to 4
Set Stage to 5
EndIf

If DummyRef.GetSleeping == 3                            ; check if dummy has arrived and is sleeping

If SelSleeptTime == 0

;  ------- Player canceld sleep?

;                PrintC "FNNsys: Stage 3 Player canceled sleep"

Set TimerE to 10
DummyRef.RemoveScriptpackage FNNsysSleepWalkPackage            ; dummy should walk to already rotated dummypos
DummyRef.AddScriptpackage FNNsysWakeWalkPackage
Set WellRested to 0                    ; player didn't sleep here: No well rested
set Stage to 5                            ; to 5

Else

;  ------- Set the sleep timescale

Set OrgTimeScale to TimeScale                    ; get the timescale
Set SleepTimeScale to 1920                        ; change the timescale 1890

;  ------- Is it disturbed sleep?

If SleepDisturbed == 1                                ; player gets disturbed
;                    PrintC "FNNsys: Stage3 Sleep disturbance is calculated"
set SleepDisturbedStart to 3 + ( GetRandomPercent * (SelSleeptTime -3) / 99) ; between 3 & Sleeptime
If SleepDisturbedStart == SelSleeptTime
Set SleepDisturbedStart  to SleepDisturbedStart - 1
EndIf
EndIf

Set TimerD to (SelSleeptTime - 1)    * 2                 ; set the timer to the selected double sleeptime in seconds
Set SecCnt to TimerD
Set Stage to 4                                            ; to main sleeping stage

EndIf

EndIf

EndIf

; ---------------------------- Stage 4: Main Sleep Stage, Snorr, Disturbance,

If Stage == 4

If DummyRef.IsInCombat == 1 || PlayerRef.IsInCombat == 1
Set PlDuCombat to 1
Set TimerE to 4
Set Stage to 5
EndIf

If OneSecond == 0                                            ; prepare one second timer for idle talk and time passing
Set OneSecond to 1
Set TimerF to 1
Set Timescale to SleepTimeScale                    ; set the sleep timescale
EndIf

If TalkCnt == SnorrFreq                                    ; do the snorring with constitution based frequency
If SlSnorr == 0                                            ; config menu check
;                PrintC "FNNsys: Stage4 Player Snorrs"
DummyRef.Say IdleChatter
EndIf
Set TalkCnt to 0
EndIf

if ( TimerF > 0 )                                                ; one second timer disturbance and idle talk
Set TimerF to ( TimerF - GetSecondsPassed )
else
Set OneSecond to 0

If PlayerRef.GetAv SleepDeprevation > 38
PlayerRef.DamageAv SleepDeprevation -36         ; restore Sleep to the player
EndIf

Set TalkCnt to TalkCnt + 1                            ; counter for idle chatter
Set SecCnt to SecCnt - 1                                ; counts only the seconds for random events
Set Timescale to OrgTimescale
EndIf

If SecCnt == SleepDisturbedStart                        ; time for disturbance is reached start the action
If SleepDisturbedStart > 1
;                PrintC "FNNsys: Stage4 Disturbance has started"
set SleepDisturbedStart to -1
set FNNsysAmbush.Stage to 1
startquest FNNsysAmbush
stopquest FNNsys
EndIf
EndIf

;  ------- Main sleep timer

if ( TimerD > 0 )                                                ; main timer for dummy sleep
Set TimerD to ( TimerD - GetSecondsPassed )
else

; ------- end dummy sleep cycle
DummyRef.RemoveScriptpackage FNNsysSleepWalkPackage            ; dummy should walk to already rotated dummypos
DummyRef.AddScriptpackage FNNsysWakeWalkPackage
DummyRef.evp

Set TimerE to 12                                        ;  15 seconds as fallback if something goes wrong
Set Stage to 5

EndIf

EndIf

If Stage == 5

If DummyPlBedMove == 2

; ---- get rid of the fake bed

;            PrintC "FNNsys: Stage 5 FakeBed is removed"

DummyPlBedMoveRef.Disable
DummyPlBedMoveRef.MarkforDelete
Set DummyPlBedMove to 0

EndIf

If Timescale == SleepTimescale
Set Timescale to OrgTimescale
EndIf

If ( TimerE > 0 )
Set TimerE to ( TimerE - GetSecondsPassed )
Else

If PlDuCombat == 1
PlayerRef.moveto DummyRef
Set PlDuCombat to 0
EndIf

PlaySound UIItemsClothingUp                        ; for immersion

Set FNNsys0.fAngle to DummyRef.GetAngle Z                ; get angle of dummy player
PlayerRef.SetAngle Z FNNsys0.fAngle                        ; correct player angle to fit dummy angle

DummyRef.RemoveAllItems FNNsysSleeepWearContRef 1    ; get sleepwear back
DummyRef.stopcombat                                ; to make it harder for the player

Set DummyHealth to DummyHealth - (DummyRef.GetAV Health)

PlayerRef.SetPos X FNNsys0.orgxpos                        ; place player back
PlayerRef.SetPos Y FNNsys0.orgypos
PlayerRef.SetPos Z FNNsys0.orgzpos

PlayerRef.setActorAlpha 1                            ; make player visible again

DummyRef.ResetHealth                                ; heal the dummy before it is sent back to holding
DummyRef.restoreav perceptioncondition 100
DummyRef.restoreav endurancecondition 100
DummyRef.restoreav leftattackcondition 100
DummyRef.restoreav leftmobilitycondition 100
DummyRef.restoreav rightattackcondition 100
DummyRef.restoreav rightmobilitycondition 100

DummyRef.moveto DummyPrepareRef                    ; remove dummy back in hidden cell
PrepareNPCBedXmRef.moveto DummyPrepareRef    ; remove markers back to hidden cell
DummyXMHRef.moveto DummyPrepareRef

If DummyRef.GetDead == 1
PlayerRef.Killactor                                 ; dummy dead, player dead
Else
;                PrintC "FNNsys: Stage5 Player gets damage of Dummy"
PlayerRef.Damageav Health DummyHealth    ; give player some nice surprises from dummy
EndIf

EnablePlayerControls                                ; cutscene is over

If WellRested == 1
;                PrintC "FNNsys: Stage5 Player gets Well Rested"
Set WellRested to 0
PlayerRef.CastImmediateOnSelf WellRestedSpell
EndIf

If DogPee == 1
;                PrintC "FNNsys: Stage5 Player gets DogStinkSpell"
Set DogPee to 0
PlayerRef.CastImmediateOnSelf FNNsysAmbDogStinkSpell
EndIf

Set RealSleepStopTime to GameDayspassed
Set RealSleepTime to (RealSleepStopTime/ 0.041667) - (RealSleepStartTime/ 0.041667)
;            PrintC "RealSleepTime %f" RealSleepTime

Set hcSleepdep to PlayerRef.GetAv SleepDeprevation

; ------- compensate the last sleep hour the Deprevation should be 2 like in the original game after a full sleep
If hcSleepdep < 38 && hcSleepdep > 2
Set hcSleepdep to 2 - hcSleepdep
PlayerRef.DamageAv SleepDeprevation hcSleepdep        ; restore Sleep to the player
EndIf

Set SelSleeptTime to 0
Set SleepNotCancled to 0
Set SleepDisturbed to 0                                                    ; back to default
Set Stage to 0

If FNNsys0.FNNsysSave == 0
AutoSave
EndIf

StopQuest FNNsys
EndIf

EndIf

End

Begin Menumode 1012

If DummyPlBedMove == 2
Set DummyPlBedMove to 3
EndIf

If GetPCSleepHours > 0                                    ; get the hours the PC tries to sleep

;        PrintC "FNNsys: Menumode 1012 Player tries to sleep"

set SelSleeptTime to GetPCSleepHours            ; get the adjusted value
set RealSleepStartTime to GameDaysPassed    ; get the actual Time (lay down included)

SetPCSleepHours 0                                    ; set the hours to 0
set Stage to 3                                            ; start the dummy sleep

WakeUpPc                                                ; get rid of the menu

EndIf

End

Цитата BsX

ну вот так вот будет, получается.

Да. Нужно ведь одни и те же сутки считать от полуночи до полуночи, т.е. - с 00⁰⁰ до 24⁰⁰ часов. И цифры рассматривать именно в таком диапазоне, от 0 до 24.
Время с 10 утра до 9(21) вечера будет как (GetCurrentTime >= 10 утра И GetCurrentTime <= 21 вечера).
А все остальные часы в сутках  будут ИЛИ (или меньше 10 утра или больше 21 вечера)

ЗЫ. В Картотеке подправила.